version = '1.0.0-build214'
target = '1.4'
release = true

buildscript {
    repositories {
        mavenRepo(urls: [mavenPublicRepositoryURL]) {
            snapshotTimeout = org.gradle.api.internal.artifacts.ivyservice.GradleIBiblioResolver.ALWAYS
        }
    }
    dependencies { classpath 'org.tmatesoft.build:build:0.9.4-SNAPSHOT' }
}

task wrapper(type: Wrapper) {}

configure(rootProject) {
    apply plugin: 'idea'
} 

subprojects {

    apply plugin : 'java'
    apply plugin : 'eclipse'
    apply plugin : 'idea'
    apply plugin : 'build'

    sourceCompatibility = target
    targetCompatibility = target

    jar {
        metaInf {
            from rootProject.file('LICENSE.txt')
        }
    }

    task sourcesJar(type: Jar) {
        description = 'Builds Java Sources Jar'
        from sourceSets.main.java.srcDirs
        classifier = 'sources'
    }

    artifacts {
        maven jar, sourcesJar
    }
}

configure(project(':trilead-ssh2-osgi')) {
    apply plugin : 'osgi'    
    dependencies {
        compile project(':trilead-ssh2')
    }    
    sourcesJar.enabled = false    
    artifacts {
        maven jar
    }
    conf2ScopeMappings.mappings.remove(configurations.compile)    
}