version = '1.0.0-build217'

project.ext {
   target = '1.4'
   release = true
}

apply from: 'build.pom.gradle'

buildscript {
    apply from: 'build.defaults.gradle'
    configurations.all {
        resolutionStrategy {
            cacheChangingModulesFor 0, 'seconds'
            cacheDynamicVersionsFor 0, 'seconds'
        }
    }
    repositories {
        maven {
           url project.ext.buildPluginRepositoryURL
        }
    }
    dependencies { classpath 'org.tmatesoft.build:build:0.9.9' }
}

task wrapper(type: Wrapper) {}

configure(rootProject) {
    apply plugin: 'idea'
    apply plugin: 'eclipse'
} 

subprojects {
  
    apply plugin : 'java'
    apply plugin : 'eclipse'
    apply plugin : 'idea'
    apply plugin : 'signing'
    apply plugin : 'build'

    sourceCompatibility = target
    targetCompatibility = target

    jar {
        metaInf {
            from rootProject.file('LICENSE.txt')
        }
    }

    task sourcesJar(type: Jar) {
        description = 'Builds Java Sources Jar'
        from sourceSets.main.java.srcDirs
        classifier = 'sources'
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        description="Builds Javadoc Jar"
        from "$docsDir/javadoc"
        classifier = 'javadoc'
    }

    artifacts {
        maven jar, sourcesJar, javadocJar
    }
}

configure(project(':trilead-ssh2-osgi')) {
    apply plugin : 'osgi'    

    dependencies {
        compile project(':trilead-ssh2')
    }    

    artifacts {
        maven jar
    }

    conf2ScopeMappings.mappings.remove(configurations.compile)
}